Aqui tentarei trazer alguma ajuda ao desenvolvimento de programas em Delphi. Se voce gostar delas ou tiver algo a compartilhar, mande um e-mail.

• Executando um programa em DOS e fechando sua janela em seguida
• Mudando o texto de um TEdit no seu evento OnChange
• Encolhendo o executável
• Pegando a linha e coluna atuais de um memo
• Mudando o fonte de um menu
• Configurações internacionais
• Extraindo ícones de um executável
• Como acessar o ambiente do DOS
• Filtrando e classificando tabelas em Delphi 1.0
• Acessando botões de um DBNavigator
• Fazendo a tecla Enter funcionar como Tab
• Compactando tabelas
• Trabalhando com grids multiseleções
• Listando todas janelas abertas
• Convertendo a primeira letra de um TEdit para maiúscula
• Fazendo pesquisa incremental numa tabela
• Fazendo pesquisa incremental numa query (D2/D3)
• Criando janelas não retangulares (D2/D3)
• Detectando a finalização do Windows
• Movimentando o ponteiro do mouse
• Posicionando o cursor em uma linha de um Memo ou RichEdit
• Movendo uma form sem barra de título
• Alinhando itens do menu principal à direita
• Mostrar e alterar resoluções de vídeo
• Detectando quando o mouse está sobre um componente
• Detectando a finalização do Windows
• Desenhando com tipos diferentes de linhas
• Chamando a caixa de diálogo de conexão da Rede DialUp
• Acessando membros protegidos de um objeto
• Escondendo janelas filhas MDI minimizadas
• Escondendo e mostrando a barra de tarefas do Windows
• Senha de tabelas Paradox no programa
• Executando ações padrão de um Ole Container

Executando um programa em DOS e fechando sua janela em seguida

Quando voce exeuta um programa DOS no Windows95, sua janela permanece aberta até ser fechada pelo usuário. Para executar um programa DOS que fecha sua janela após a execução, deve ser especificado "command.com /c programa"na linha de comando. Usando a função da API WinExec para executar um programa chamado progdos.exe, a chamada deve ser:

WinExec('command.com /c progdos.exe',sw_ShowNormal);

Se o programa deve ser executado sem que seja visualizado pelo usuário, o segundo parâmetro deve ser sw_Hide. Deve ser especificada a extensão .com senão o programa não será executado.

Mudando o texto de um TEdit no seu evento OnChange

Se o texto de um TEdit for mudado no seu evento OnChange, este evento será chamado recursivamente até acabar com o espaço de pilha. Para fazer isso, deve-se setar o evento OnChange para NIL antes de mudar o texto, voltando ao original depois, desta maneira:

procedure Edit1Change(Sender : TObject);
begin
  Edit1.OnChange := NIL;
  if Edit1.Text = 'Texto' then
    Edit1.Text := 'Novo Texto';
  Edit1.OnChange := Edit1Change;
end;

Esta dica também vale para evento OnValidate.

Encolhendo o executável

Em Delphi 1.0, marcando a checkbox Optimize for size and load time, em Options/Project/Linker não funciona (aparece uma mensagem de disco cheio, mesmo com muito espaço). Delphi 1.0 vem com um programa DOS, W8LOSS, que faz o mesmo. Para usá-lo, deve-se teclar o seguinte:

W8LOSS programa.exe

Isto encolherá o executável em aproximadamente 20%, diminuindo o tempo de carga.

Pegando a linha e coluna atuais de um memo

Para pegar a linha e coluna de um memo voce deve utilizar o seguinte:

With Memo1 do begin
  Line := Perform(EM_LINEFROMCHAR,SelStart, 0);
  Column := SelStart - Perform(EM_LINEINDEX, Line, 0);
end;

Mudando o fonte de um menu

Para mudar o fonte de um menu voce deve esquecer o Menu Designer e criar os itens usando a função da API AppendMenu, utilizando o parâmetro MF_OWNERDRAW, no evento OnCreate da Form. Então use as mensagens WM_MEASUREITEM e WM_DRAWITEM para desenhar os menus. Pegue um exemplo.

Configurações internacionais

Normalmente o Delphi pega os formatos de data/hora, moeda e formato numérico da Configuração Internacional do Painel de Controle. Isto pode levar a erros quando avaliando datas, numeros ou listas. Para evitar estes erros, voce pode mudar as constantes definidas no Delphi, como DecimalSeparator, ShortDateFormat e outros desta maneira:

DecimalSeparator := '.';
ShortDateFormat := 'mm/dd/yy';

Isto terá precedência sobre a configuração padrão. Para uma lista completa das variáveis, procure em Currency Formatting Variables na ajuda do Delphi.

Extraindo ícones de um executável

Para extrair ícones de um executável, deve-se usar a função da API ExtractIcon. Ela usa 3 parâmetros:

Instance - Instancia da aplicação

FileName - Nome do executável. Deve ser um PChar

NumIcon - Número do ícone a ser recuperado. Se for Word(-1), a função retorna a quantidade de ícones no executável.

Pegue um exemplo.

Como acessar o ambiente do DOS

Para acessar as variáveis de ambiente do DOS, deve-se usar a função da API GetDosEnvironment. Ela retorna um PChar que pode ser avaliado. Pegue um exemplo.

Filtrando e classificando tabelas em Delphi 1.0

Para filtrar e classificar tabelas em Delphi 1.0, voce pode usar um arquivo QBE (Query by Example) como propriedade TableName de uma TTable. Isto permite filtrar, classificar ou unir tabelas usando o componente TTable. Arquivos QBE podem ser criados no Database Desktop.

Acessando botões do DBNavigator

O DBNavigator tem uma matriz protegida Buttons que acessa os seus botões. Criando um descendente do DBNavigator permite acessá-los e mudar suas propriedades. TBSNavigator é um componente que permite mudar seu estado Enabled ou sua figura.

Fazendo a tecla Enter funcionar como Tab

Para fazer a tecla Enter funcionar como Tab é um processo de 3 passos


1) Setar a propriedade KeyPreview da Form para True
2) Setar a propriedade Default de todos os botões da Form para False
3) Criar um evento OnKeyPress para a Form como este:


procedure TForm1.FormKeyPress(Sender: TObject; var Key: Char);
begin
  if Key = #13 then begin
    Key := #0;
  if (Sender is TDBGrid) then
    TDBGrid(Sender).Perform(WM_KeyDown,VK_Tab,0)
  else
    Perform(Wm_NextDlgCtl,0,0);
  end;
end;

Dica complementada por: Antonio Carlos Maduro

Compactando tabelas

Para compactar (remover fisicamente todos registros apagados) de uma tabela Paradox deve-se utilizar o seguinte código


procedure ParadoxPack(Table : TTable);
var
  TBDesc : CRTblDesc;
  hDb: hDbiDb;
  TablePath: array[0..dbiMaxPathLen] of char;
begin
  FillChar(TBDesc,Sizeof(TBDesc),0);
  with TBDesc do begin
    StrPCopy(szTblName,Table.TableName);
    StrPCopy(szTblType,szParadox);
    bPack := True;
  end;
  Table.Open;
  hDb := nil;
  Check(DbiGetDirectory(Table.DBHandle, True, TablePath));
  Table.Close;
  Check(DbiOpenDatabase(nil, 'STANDARD', dbiReadWrite,
    dbiOpenExcl,nil,0, nil, nil, hDb));
  Check(DbiSetDirectory(hDb, TablePath));
  Check(DBIDoRestructure(hDb,1,@TBDesc,nil,nil,nil,False));
  Table.Open;
end;

Para compactar tabelas Dbase use o seguinte comando

  DBIPackTable(Table1.DBHandle,Table1.Handle,nil,nil,True);

Trabalhando com grids multiseleções

As grids multiseleções do Delphi 2.0 têm uma propriedade não documentada chamada SelectedRows, uma lista de TBookmark. Você pode utilizá-la com um código como este:


With DbGrid1 do begin
  for i := 0 to Pred(SelectedRows.Count) do begin
    DataSource.DataSet.Bookmark := SelectedRows[i];
    {o dataset está posicionado na seleção.}
  end;
end;

Listando todas janelas abertas

Para listar (pegar) todas janelas abertas, deve-se usar a funcao da API EnumWindows, que usa uma funcao Callback, com dois parametros, um Handle para a janela e um ponteiro. Voce pode usá-la com um código semelhante a este (Este lista as janelas abertas, mesmo invisíveis, em uma listbox):


function EnumWindowsProc(Wnd : HWnd;Form : TForm1) : Boolean; Export; {$ifdef Win32} StdCall; {$endif}
var
  Buffer : Array[0..99] of char;
begin
  GetWindowText(Wnd,Buffer,100);
  if StrLen(Buffer) <> 0 then
    Form.ListBox1.Items.Add(StrPas(Buffer));
  Result := True;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  EnumWindows(@EnumWindowsProc,LongInt(Self));
end;

Convertendo a primeira letra de um EditBox para maiúsculas

Para converter a primeira letra de um EditBox para maiúsculas este código pode ser utilizado:


procedure TForm1.Edit1Change(Sender: TObject);
var
  OldStart : Integer;
begin
  With Edit1 do
    if Text <> '' then begin
      OnChange := NIL;
      OldStart := SelStart;
      Text := UpperCase(Copy(Text,1,1))+LowerCase(Copy(Text,2,Length(Text)));
      SelStart := OldStart;
      OnChange := Edit1Change;
    end;
end;

Fazendo pesquisa incremental numa tabela

Para fazer pesquisa incremental numa tabela usando um EDIT, deve-se colocar o seguinte código em seu evento OnChange:


procedure TForm1.Edit1Change(Sender: TObject);
begin
  With Edit1 do
    if Text <> '' then
      Table1.FindNearest([Text]);
end;

Fazendo busca incremental numa Query

Para fazer pesquisa incremental numa query usando um EDIT, deve-se colocar o seguinte código em seu evento OnChange: (isto funciona somente em D2/D3):


procedure TForm1.Edit1Change(Sender: TObject);
begin
  With Edit1 do
    if Text <> '' then begin
      Query1.Filter := 'codigo = '''+Edit1.Text+'''';
      Query1.FindFirst;
    end;
end;

Outra maneira poderia ser


procedure TForm1.Edit1Change(Sender: TObject);
begin
  With Edit1 do
    if Text <> '' then
      Query1.Locate('codigo',Edit1.Text,[loPartialKey]);
end;

Criando janelas não retangulares (D2/D3)

Para criar uma janela não retangular, voce deve criar uma Região do Windows e usar a função da API SetWindowRgn, desta maneira (isto funciona apenas em D2/D3):


var
  hR : THandle;
begin
  {cria uma Região elíptica}
  hR := CreateEllipticRgn(0,0,100,200);
  SetWindowRgn(Handle,hR,True);
end;

Colaboração de : Serkan Aksu

Detectando a finalização do Windows

Para detectar a finalização do Windows, deve-se capturar a mensagem WM_ENDSESSION. Estes passos devem ser tomados:
Declarar uma rotina de manipulação de mensagens na sessao private de sua form:


procedure WMEndSession(var Msg : TWMEndSession); message WM_ENDSESSION;

Adicionar a procedure à seção implementation de sua unit:


procedure TForm1.WMEndSession(var Msg : TWMEndSession);
begin
  if Msg.EndSession = TRUE then
    ShowMessage('O Windows está finalizando ' + #13 + 'às ' +
      FormatDateTime('c', Now));
  inherited;
end;

Dica submetida por Steve Harman

Movimentando o ponteiro do mouse

Para movimentar o ponteiro do mouse sem intervenção do usuário, deve-se usar um TTimer e colocar o seguinte código em seu evento OnTimer:


procedure TForm1.Timer1Timer(Sender: TObject);
var
   pt:tpoint;
begin
  getcursorpos(pt);
  pt.x := pt.x + 1;
  pt.y := pt.y + 1;
  if pt.x>=screen.width-1 then setcursorpos(0,pt.y);
  if pt.y>=screen.height-1 then setcursorpos(pt.x,0);
end;

Dica submetida por Serkan Aksu

Posicionando o cursor numa linha de um Memo ou RichEdit

Para posicionar o cursor em uma linha de um Memo ou RichEdit, deve-se utilizar o seguinte:

With Memo1 do
  SelStart := Perform(EM_LINEINDEX, Linha, 0);

Movendo uma form sem barra de título

Para movimentar uma form sem barra de título, deve-se tratar a mensagem WM_NCHITTEST, desta maneira:

type
  TForm1 = class(TForm)
  public
    procedure WMNCHitTest(var M: TWMNCHitTest); message WM_NCHitTest;
  end;

var
  Form1: TForm1;

implementation
{$R *.DFM}

procedure TForm1.WMNCHitTest(var M: TWMNCHitTest);
begin
  inherited;
  if M.Result = htClient then {se o mouse foi clicado na form}
    M.Result := htCaption; {faz o Windows pensar que foi na barra de título}
end;
Dica enviada por Serkan Aksu

Alinhando itens do menu principal à direita

Para alinhar itens do menu principal à direita, deve-se utilizar o seguinte código:


{Isto justifica todos itens à direita do selecionado}

procedure SetJustify(Menu: TMenu; MenuItem: TMenuItem; Justify: Byte);
{$IFDEF WIN32}
var
  ItemInfo: TMenuItemInfo;
  Buffer: array[0..80] of Char;
{$ENDIF}
begin
{$IFDEF VER80}
  MenuItem.Caption := Chr(8) + MenuItem.Caption;
{$ELSE}
  ItemInfo.cbSize := SizeOf(TMenuItemInfo);
  ItemInfo.fMask := MIIM_TYPE;
  ItemInfo.dwTypeData := Buffer;
  ItemInfo.cch := SizeOf(Buffer);
  GetMenuItemInfo(Menu.Handle, MenuItem.Command, False, ItemInfo);
  if Justify = 1 then
    ItemInfo.fType := ItemInfo.fType or MFT_RIGHTJUSTIFY;
  SetMenuItemInfo(Menu.Handle, MenuItem.Command, False, ItemInfo);
{$ENDIF}
end;
Dica enviada por Eddie Shipman

Mostrar e alterar resoluções de vídeo

Para mostrar as resoluções de vídeo disponíveis, deve-se usar a função da API EnumDisplaySettings: ela pega todos os modos de vídeo disponíveis.
Para alterar os modos, deve-se usar a função ChangeDisplaySettings, que muda a resolução de vídeo e quantidade de cores. Pegue um exemplo.

Detectando quando o mouse está sobre um componente

Quando o mouse entra na área de um componente, Delphi envia a mensagem CM_MouseEnter. Quando sai, o Delphi envia uma mensagem. Tratando estas duas mensagens, pode-se detectar quando o mouse está sobre um componente. O componente Fly-Over label mostra esta técnica.

Detectando a finalização do Windows

Quando o Windows está finalizando, ele envia a mensagem WM_QueryEndSession para todas aplicações abertas. Para detectar (e impedi-la), deve-se definir um manipulador para esta mensagem. Ponha esta definição na seção privada de sua form:



procedure WMQueryEndSession(var Msg : TWMQueryEndSession); message WM_QueryEndSession;
E ponha este método na seção implementation da unit:

procedure TForm1.WMQueryEndSession(var Msg : TWMQueryEndSession);
begin
  if MessageDlg('Fecha o Windows ?', mtConfirmation, [mbYes,mbNo], 0) = mrNo then
    Msg.Result := 0
  else
    Msg.Result := 1;
end;

Desenhando com tipos diferentes de linhas

O Windows permite desenhar linhas onde cada pixel é outro tipo de primitiva ou desenho com a função LineDDA. Ela precisa de uma função "callback", que será chamada quando um pixel deve ser desenhado. Ali podem ser postas as rotinas de desenho. A rotina a seguir desenha um retângulo a cada 4 pixels:

TForm1 = class(TForm)
  procedure FormCreate(Sender: TObject);
  procedure FormPaint(Sender: TObject);
public
  DrawNow : Integer;
end;

var
  Form1: TForm1;

procedure DrawPoint(x,y : Integer;lpData : LParam); stdcall;

implementation

{$R *.DFM}

procedure DrawPoint(x,y : Integer;lpData : LParam);
begin
  with TObject(lpData) as TForm1 do begin
    if DrawNow mod 4 = 0 then
      Canvas.Rectangle(x-2,y-2,x+3,y+3);
    Inc(DrawNow);
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  DrawNow := 0;
end;

procedure TForm1.FormPaint(Sender: TObject);
begin
  LineDDA(0,0,Width,Height,@DrawPoint,Integer(Self));
end;

Chamando a caixa de diálogo de conexão da rede DialUp

Para chamar a caixa de diálogo da conexão da rede DialUp, pode-se usar o WinExec, como a seguir:

procedure TForm1.Button1Click(Sender: TObject);
begin
  winexec(PChar('rundll32.exe rnaui.dll,RnaDial '+Edit1.Text),sw_show);
end;
Dica enviada por Ronaldo R. Campos

Acessando Membros Protegidos de um Objeto

Normalmente, você não pode acessar membros protegidos de um objeto. Mas Delphi deixa você acessar membros protegidos se o objeto foi definido na mesma unit. Assim, você pode definir um objeto derivado e fazer a mudança de tipo onde quer usar o membro protegido. Seria algo assim:

THackControl = class(TCustomEdit)
end;
Depois de definir esta classe, você pode acessar todos membros protegidos de TCustomEdit, com ebjetos de classe derivadas com um código como esse:

THackControl(MyEdit).Color := clBlack;

Escondendo janelas filhas minimizadas

Para esconder janelas filhas minimizadas, basta capturar a mensagem WM_Size, desta maneira:

type
  TForm1 = class(TForm)
  public
    procedure WMSize(var M : TWMSIZE);Message WM_Size;
  end;

implementation

procedure TForm1.WMSize(var M:TWMSIZE);
begin
  if M.SizeType=Size_Minimized then
    showwindow(Handle,Sw_Hide);
end;

Dica submetida por Serkan Aksu

Escondendo e mostrando a barra de tarefas do Windows

Para esconder a barra de tarefas do Windows, usa-se um código como esse:

procedure TForm1.Button1Click(Sender: TObject);
var
  hTaskBar :Thandle;
begin
  hTaskBar := FindWindow('Shell_TrayWnd',Nil);
  ShowWindow(hTaskBar,Sw_Hide);
end;

Para mostrar a barra de tarefas do Windows, usa-se este código:


procedure TForm1.Button2Click(Sender: TObject);
var
  hTaskBar :Thandle;
begin
  hTaskBar := FindWindow('Shell_TrayWnd',Nil);
  ShowWindow(hTaskBar,Sw_Normal);
end;

Dica submetida por Huescli Serra Lima

Senha de tabelas Paradox no programa

Para dar a senha de uma tabela Paradox no programa, pode-se usar este código:

procedure TForm1.FormCreate(Sender: TObject);
begin
  Session.AddPassWord('MyPass');
  Table1.Acive := True;
end;

Dica submetida por Huescli Serra Lima

Executando ações padrão de um Ole Container

Para executar ações padrão de um Ole Container (abrir um documento Word ou Excel ou rodar uma apresentação Powerpoint), pode-se usar este código:

procedure TForm1.Button1Click(Sender: TObject);
begin
  OleContainer1.DoVerb(ovprimary);
end;

Dica submetida por Huescli Serra Lima

If you want to be notified of updates, please join the mailing list

Se voce quer ser notificado de atualizações, assine a lista

Atualizado em 19/11/1998
Bruno Sonnino